Utilizando Recordsets desconectados no ASP

Boa tarde computêros…

Uma das formas de melhorarmos o desempenho dos sistemas com ASP é liberar os objetos ADO assim que possível, com isso deixamos livre os recursos usados por esses objetos.
Para fazermos uso do Recordset desconectado precisaremos definir a propriedade CursorLocation para adUseClient (3) e a propriedade ActiveConnection para Nothing, desconectando o recordset e liberando os recursos.

Segue um exemplo de Utilização de Recordsets desconectados em VBScript:

<%
	Option Explicit

	'Constantes ADODB
	Const adUseClient = 3

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

	'Variavel que possui a string de conexão com o banco de dados
	Dim  sConnectionString : sConnectionString = "PROVIDER=SQLOLEDB.1;SERVER=SERVIDOR;DATABASE=BASE;UID=USUARIO;PWD=SENHA;"

	'Criando os objetos de conexao e recordset
	Dim conexao: Set conexao = Server.CreateObject("ADODB.Connection")
	Dim rs : Set rs = Server.CreateObject("ADODB.recordset")

	'Abrindo a conexão com a connection string
	conexao.Open sConnectionString

	'Cursor no modo cliente
	rs.CursorLocation = adUseClient

	Dim SQL : SQL = "SELECT campo FROM TABELA"

	'abrindo o recordset
	rs.Open SQL, conexao

	'Desconectando o recordset
	Set rs.ActiveConnection = Nothing

	'Fechando a conexão
	conexao.Close

	'Limpando o objeto de conexão
	Set conexao = Nothing

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
	''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
	' A partir deste ponto o recordset desconectado pode ser utilizado '
	''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
	Response.Write(rs.eof)
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

	'Desconectando e limpando o objeto do recordset
	rs.Close
	Set rs = Nothing
%>

É isso aí computêros, fica a dica.